terraform version 0.12.29

main.tf

@@ -8,17 +8,17 @@ variable "cidr" {
 
 variable "availability_zones" {
   description = "List of availability zones"
-  type        = "list"
+  type        = list(string)
 }
 
 variable "public_subnets" {
   description = "List of public subnets to availability zones"
-  type        = "list"
+  type        = list(string)
 }
 
 variable "private_subnets" {
   description = "List of private subnets to availability zones"
-  type        = "list"
+  type        = list(string)
 }
 
 variable "enable_dns_hostnames" {
@@ -32,126 +32,131 @@ variable "enable_dns_support" {
 }
 
 resource "aws_vpc" "mod" {
-  cidr_block           = "${var.cidr}"
-  enable_dns_hostnames = "${var.enable_dns_hostnames}"
-  enable_dns_support   = "${var.enable_dns_support}"
+  cidr_block           = var.cidr
+  enable_dns_hostnames = var.enable_dns_hostnames
+  enable_dns_support   = var.enable_dns_support
 
-  tags { 
-    Name = "${var.name}"
+  tags = {
+    Name = var.name
   }
 }
 
 resource "aws_subnet" "public" {
-  lifecycle { create_before_destroy = true }
+  lifecycle {
+    create_before_destroy = true
+  }
 
-  vpc_id                  = "${aws_vpc.mod.id}"
-  cidr_block              = "${element(var.public_subnets, count.index)}"
-  availability_zone       = "${element(var.availability_zones, count.index)}"
-  count                   = "${length(var.public_subnets)}"
+  vpc_id                  = aws_vpc.mod.id
+  cidr_block              = element(var.public_subnets, count.index)
+  availability_zone       = element(var.availability_zones, count.index)
+  count                   = length(var.public_subnets)
   map_public_ip_on_launch = true
 
-  tags {
+  tags = {
     Name = "${var.name}.public.${element(var.availability_zones, count.index)}"
   }
 }
 
 resource "aws_subnet" "private" {
-  lifecycle { create_before_destroy = true }
+  lifecycle {
+    create_before_destroy = true
+  }
 
-  vpc_id            = "${aws_vpc.mod.id}"
-  cidr_block        = "${element(var.private_subnets, count.index)}"
-  availability_zone = "${element(var.availability_zones, count.index)}"
-  count             = "${length(var.private_subnets)}"
+  vpc_id            = aws_vpc.mod.id
+  cidr_block        = element(var.private_subnets, count.index)
+  availability_zone = element(var.availability_zones, count.index)
+  count             = length(var.private_subnets)
 
-  tags {
+  tags = {
     Name = "${var.name}.private.${element(var.availability_zones, count.index)}"
   }
 }
 
 resource "aws_internet_gateway" "mod" {
-  vpc_id = "${aws_vpc.mod.id}"
+  vpc_id = aws_vpc.mod.id
 
-  tags {
-    Name = "${var.name}"
+  tags = {
+    Name = var.name
   }
 }
 
 resource "aws_eip" "nat" {
   vpc   = true
-  count = "${length(var.public_subnets)}"
+  count = length(var.public_subnets)
 }
 
 resource "aws_nat_gateway" "nat" {
-  subnet_id     = "${element(aws_subnet.public.*.id, count.index)}"
-  allocation_id = "${element(aws_eip.nat.*.id, count.index)}"
-  count         = "${length(var.public_subnets)}"
-  depends_on    = ["aws_internet_gateway.mod"]
+  subnet_id     = element(aws_subnet.public.*.id, count.index)
+  allocation_id = element(aws_eip.nat.*.id, count.index)
+  count         = length(var.public_subnets)
+  depends_on    = [aws_internet_gateway.mod]
 }
 
 resource "aws_route_table" "public" {
-  vpc_id = "${aws_vpc.mod.id}"
+  vpc_id = aws_vpc.mod.id
 
-  tags { 
+  tags = {
     Name = "${var.name}.public"
   }
 }
 
 resource "aws_route_table" "private" {
-  vpc_id = "${aws_vpc.mod.id}"
-  count  = "${length(var.private_subnets)}"
+  vpc_id = aws_vpc.mod.id
+  count  = length(var.private_subnets)
 
-  tags {
+  tags = {
     Name = "${var.name}.private.${element(var.availability_zones, count.index)}"
   }
 }
 
 resource "aws_route" "public_internet_gateway" {
-  route_table_id         = "${aws_route_table.public.id}"
+  route_table_id         = aws_route_table.public.id
   destination_cidr_block = "0.0.0.0/0"
-  gateway_id             = "${aws_internet_gateway.mod.id}"
+  gateway_id             = aws_internet_gateway.mod.id
 }
 
 resource "aws_route" "nat_gateway" {
-  route_table_id         = "${element(aws_route_table.private.*.id, count.index)}"
+  route_table_id         = element(aws_route_table.private.*.id, count.index)
   destination_cidr_block = "0.0.0.0/0"
-  nat_gateway_id         = "${element(aws_nat_gateway.nat.*.id, count.index)}"
-  count                  = "${length(var.public_subnets)}"
+  nat_gateway_id         = element(aws_nat_gateway.nat.*.id, count.index)
+  count                  = length(var.public_subnets)
 
-  depends_on             = ["aws_route_table.private"]
+  depends_on = [aws_route_table.private]
 }
 
 resource "aws_route_table_association" "public" {
-  subnet_id      = "${element(aws_subnet.public.*.id, count.index)}"
-  route_table_id = "${aws_route_table.public.id}"
-  count          = "${length(var.public_subnets)}"
+  subnet_id      = element(aws_subnet.public.*.id, count.index)
+  route_table_id = aws_route_table.public.id
+  count          = length(var.public_subnets)
 }
 
 resource "aws_route_table_association" "private" {
-  subnet_id      = "${element(aws_subnet.private.*.id, count.index)}"
-  route_table_id = "${element(aws_route_table.private.*.id, count.index)}"
-  count          = "${length(var.private_subnets)}"
+  subnet_id      = element(aws_subnet.private.*.id, count.index)
+  route_table_id = element(aws_route_table.private.*.id, count.index)
+  count          = length(var.private_subnets)
 }
 
 output "private_subnets" {
-  value = ["${aws_subnet.private.*.id}"]
+  value = aws_subnet.private.*.id
 }
 
 output "public_subnets" {
-  value = ["${aws_subnet.public.*.id}"]
+  value = aws_subnet.public.*.id
 }
 
 output "vpc_id" {
-  value = "${aws_vpc.mod.id}"
+  value = aws_vpc.mod.id
 }
 
 output "public_route_table_id" {
-  value = "${aws_route_table.public.id}"
+  value = aws_route_table.public.id
 }
 
 output "private_route_table_ids" {
-  value = ["${aws_route_table.private.*.id}"]
+  value = aws_route_table.private.*.id
 }
 
 output "nat_gateway_public_ips" {
-  value = ["${aws_eip.nat.*.public_ip}"]
+  value = aws_eip.nat.*.public_ip
 }
+